Categories


Tags


如何限制同一表单被多次提交

在Internet上我们每天都会遇到数不清的表单,也看到其中大部分并没有限制用户多次提交同一个表单。缺乏这种限制有时候会产生某些预料不到的结果,如重复订阅邮件服务或重复投票等。

本文介绍在ASP应用中防止用户在当前会话期间多次提交同一表单的一个简单方法。它主要由四个子程序组成,在较为简单的应用场合,你只要将这些代码放在包含文件中直接引用即可;对于那些较为复杂的环境,我们在文章的最后给出一些改进建议。

一、基本工作过程

下面我们依次讨论这四个子程序。

(一)初始化

这里我们要在Session对象中保存两个变量,其中:

⑴ 每一个表单对应一个称为FID的唯一标识,为使该值唯一要用到一个计数器。

⑵ 每当一个表单成功提交,必须在一个Dictionary对象中存储它的FID。

我们用一个专用的过程来初始化上述数据。虽然以后各个子程序都要调用它,但实际上每一个会话期间它只执行一次:

Sub InitializeFID()

If Not IsObject(Session("FIDList")) Then

Set Session("FIDList")=Server.CreateObject("Scripting.Dictionary")

Session("FID")=0

End If

End Sub

(二)生成表单的唯一标识符

下面这个函数GenerateFID()用于生成表单的唯一标志。该函数首先将FID值加1,然后返回它:

Function GenerateFID()

InitializeFID

Session("FID") = Session("FID") + 1

GenerateFID = Session("FID")

End Function

(三)登记已提交表单

当表单成功地提交时,在Dictionary对象中登记它的唯一标识:

Sub RegisterFID()

Dim strFID

InitializeFID

strFID = Request("FID")

Session("FIDlist").Add strFID, now()

End Sub

(四)检查表单是否重复提交

在正式处理用户提交的表单之前,应该在Dictionary对象中检查它的FID是否已经登记。下面的CheckFID()函数用来完成这个工作,如已经登记,它返回FALSE,否则返回TRUE:

Function CheckFID()

Dim strFID

InitializeFID

strFID = Request("FID")

CheckFID = not Session("FIDlist").Exists(strFID)

End Function

二、如何使用

有两个地方要用到上述函数,即表单生成时与结果处理时。假设上述四个子程序已经放入包含文件Forms.inc中,下面的代码根据FID值来决定生成表单还是处理表单结果,它所描述的处理过程适合于大多数ASP应用:

< %Option Explicit%>

< !--#include file="forms.inc"-->

< HTML>

< HEAD>

< TITLE>表单提交测试< /TITLE>

< /HEAD

< BODY>

< %

If Request("FID") = "" Then

GenerateForm

Else

ProcessForm

End If

%>

< /BODY>

< /HTML>

GenerateForm负责生成表单,表单中应该含有一个隐藏的FID,如:

< %

Sub GenerateForm()

%>

< form action="< %=Request.ServerVariables("PATH_INFO")%>" method=GET>

< input type=hidden name=FID value="< %=GenerateFID()%>">

< input type=text name="param1" value="">

< input type=submit value="OK">

< /form>

< %

End Sub

%>

ProcessForm负责处理通过表单提交的内容,但在处理之前应该先调用CheckFID()检查当前表单是否已经提交,代码类如:

< %

Sub ProcessForm()

If CheckFID() Then

Response.Write "你输入的内容是" & Request.QueryString("param1")

RegisterFID

Else

Response.Write "此表单只能提交一次!"

End If

End Sub

%>

三、限制与改进措施

上面我们介绍了在当前会话期间限制同一表单被多次提交的一种方法。在实际应用中可能需要从多方面加以改进,例如:

⑴ 在登记表单ID之前检查用户输入数据的合法性,使得数据不合法时用户可以按“后退”按钮返回,在修正后再次提交同一表单。

⑵ 这种对表单提交的限制最多只能在当前会话期间有效。如果要求这种限制能够跨越多个会话,那么就要用到Cookeis或数据库来保存相关数据了。

⑶ 这种方法是不安全的。它仅用于防范误操作,不能防止熟练用户有意地多次提交同一表单。

来源:月光博客


Public @ 2022-09-01 15:46:27

IIS7关于多域名多证书多IP的部署方案

在IIS 7中,可以使用多域名、多证书和多IP的部署方案来支持多个网站或应用程序。下面是一个基本的部署方案: 1. 获取并安装多个SSL证书:每个域名对应的网站需要使用独立的SSL证书。首先,从可信的证书颁发机构 (CA) 购买或获取每个域名的SSL证书。然后,将证书安装到服务器上。 2. 配置多个IP地址:为每个域名分配不同的IP地址。可以通过网络适配器设置静态IP地址或者使用网络设备(例如

Public @ 2023-07-22 12:00:38

VPS、弹性云使用phpmyadmin导入导出MySQL数据库

1. 登录phpmyadmin 使用VPS或弹性云服务器,首先需要登录phpmyadmin控制面板。访问网站的URL后,并在网站后加上“/phpmyadmin”即可进入登录页面。输入正确的用户名和密码进行登录。 2. 进入数据库 进入phpmyadmin控制面板后,会显示所有的数据库。选择要导入或导出的数据库并进入。 3. 导出MySQL数据库 要导出MySQL数据库,选择导航栏上的“导

Public @ 2023-04-17 09:00:11

利用ASP开发Web应用

通常情况下,用户通过浏览器看到的网页大多是静态的,而随着Web 应用的发展,用户希望能够看到根据要求而动态生成的主页,例如响应用户查询数据库的要求、生成报表等。根据用户请求生成动态主页的传统方法有CGI、ISAPI 等。CGI 是根据浏览器端的http 请求激活响应进程,每一个请求对应一个进程。当同时有很多请求时,程序挤占系统资源,造成效率低下;ISAPI 针对这一缺点进行改进,利用dll(动态链

Public @ 2014-06-22 15:46:26

更多您感兴趣的搜索

0.486258s